CPPopover.j

Go to the documentation of this file.

/*
 * CPPopover.j
 * AppKit
 *
 * Created by Antoine Mercadal.
 * Copyright 2011 Antoine Mercadal.
 *
 * This library is free software; you can redistribute it and/or
 * modify it under the terms of the GNU Lesser General Public
 * License as published by the Free Software Foundation; either
 * version 2.1 of the License, or (at your option) any later version.
 *
 * This library is distributed in the hope that it will be useful,
 * but WITHOUT ANY WARRANTY; without even the implied warranty of
 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
 * Lesser General Public License for more details.
 *
 * You should have received a copy of the GNU Lesser General Public
 * License along with this library; if not, write to the Free Software
 * Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA
 */



@protocol CPPopoverDelegate <CPObject>

@optional
- (BOOL)popoverShouldClose:(CPPopover)aPopover;
- (void)popoverWillClose:(CPPopover)aPopover;
- (void)popoverDidClose:(CPPopover)aPopover;
- (void)popoverWillShow:(CPPopover)aPopover;
- (void)popoverDidShow:(CPPopover)aPopover;

@end

CPPopoverBehaviorApplicationDefined = 0;
CPPopoverBehaviorTransient          = 1;
CPPopoverBehaviorSemitransient      = 2;

var CPPopoverDelegate_popover_willShow_     = 1 << 0,
    CPPopoverDelegate_popover_didShow_      = 1 << 1,
    CPPopoverDelegate_popover_shouldClose_  = 1 << 2,
    CPPopoverDelegate_popover_willClose_    = 1 << 3,
    CPPopoverDelegate_popover_didClose_     = 1 << 4;


@implementation CPPopover : CPResponder
{
    @outlet CPViewController        _contentViewController;
    @outlet id <CPPopoverDelegate>  _delegate               @accessors(getter=delegate);

    BOOL                            _animates;
    int                             _appearance;
    int                             _behavior;

    _CPPopoverWindow                _popoverWindow;
    CPView                          _positioningView;
    int                             _implementedDelegateMethods;
}


#pragma mark -
#pragma mark Initialization

- (CPPopover)init
{
    if (self = [super init])
    {
        _animates      = YES;
        _appearance    = CPPopoverAppearanceMinimal;
        _behavior      = CPPopoverBehaviorApplicationDefined;
    }

    return self;
}


#pragma mark -
#pragma mark Getters / Setters

- (CGRect)positioningRect
{
    if (![_popoverWindow isVisible])
        return CGRectMakeZero();

    return [_popoverWindow frame];
}

- (void)setPositioningRect:(CGRect)aRect
{
    if (![_popoverWindow isVisible])
        return;

    [_popoverWindow setFrame:aRect];
}

- (CGSize)contentSize
{
    return [[_contentViewController view] frameSize];
}

- (void)setContentSize:(CGSize)aSize
{
    if (!_popoverWindow)
        [[_contentViewController view] setFrameSize:aSize];
    else
        [_popoverWindow updateFrameWithSize:aSize];
}

- (BOOL)isShown
{
    return [_popoverWindow isVisible];
}

- (void)setAnimates:(BOOL)shouldAnimate
{
    if (_animates == shouldAnimate)
        return;

    _animates = shouldAnimate;
    [_popoverWindow setAnimates:_animates];
}

- (void)setBehavior:(int)aBehavior
{
    if (_behavior == aBehavior)
        return;

    _behavior = aBehavior;
    [_popoverWindow setStyleMask:[self _styleMaskForBehavior]];
}

- (void)setDelegate:(id <CPPopoverDelegate>)aDelegate
{
    if (_delegate === aDelegate)
        return;

    _delegate = aDelegate;
    _implementedDelegateMethods = 0;

    if ([_delegate respondsToSelector:@selector(popoverWillShow:)])
        _implementedDelegateMethods |= CPPopoverDelegate_popover_willShow_;

    if ([_delegate respondsToSelector:@selector(popoverDidShow:)])
        _implementedDelegateMethods |= CPPopoverDelegate_popover_didShow_;

    if ([_delegate respondsToSelector:@selector(popoverShouldClose:)])
        _implementedDelegateMethods |= CPPopoverDelegate_popover_shouldClose_;

    if ([_delegate respondsToSelector:@selector(popoverWillClose:)])
        _implementedDelegateMethods |= CPPopoverDelegate_popover_willClose_;

    if ([_delegate respondsToSelector:@selector(popoverDidClose:)])
        _implementedDelegateMethods |= CPPopoverDelegate_popover_didClose_;
}

#pragma mark -
#pragma mark Positioning

- (void)showRelativeToRect:(CGRect)positioningRect ofView:(CPView)positioningView preferredEdge:(CPRectEdge)preferredEdge
{
    if (!positioningView)
        [CPException raise:CPInvalidArgumentException reason:"positionView must not be nil"];

    if (!_contentViewController)
        [CPException raise:CPInternalInconsistencyException reason:@"contentViewController must not be nil"];

    // If the popover is currently closing or opening, do nothing. That is what Cocoa does.
    if ([_popoverWindow isClosing] || [_popoverWindow isOpening])
        return;

    _positioningView = positioningView;

    if (!_popoverWindow)
        _popoverWindow = [[_CPPopoverWindow alloc] initWithContentRect:CGRectMakeZero() styleMask:[self _styleMaskForBehavior]];

    [_popoverWindow setPlatformWindow:[[positioningView window] platformWindow]];
    [_popoverWindow setAppearance:_appearance];
    [_popoverWindow setAnimates:_animates];
    [_popoverWindow setDelegate:self];
    [_popoverWindow setMovableByWindowBackground:NO];
    [_popoverWindow setFrame:[_popoverWindow frameRectForContentRect:[[_contentViewController view] frame]]];
    [_popoverWindow setContentView:[_contentViewController view]];

    if (![self isShown])
        [self _popoverWillShow];

    [_popoverWindow positionRelativeToRect:positioningRect ofView:positioningView preferredEdge:preferredEdge];

    if (![self isShown])
        [self _popoverWindowDidShow];
}

- (unsigned)_styleMaskForBehavior
{
    if (_behavior == CPPopoverBehaviorApplicationDefined)
        return 0;

    return CPClosableOnBlurWindowMask
}

- (void)close
{
    [self _close];
}

- (void)_close
{
    if ([_popoverWindow isClosing] || ![self isShown])
        return;

    [self _popoverWillClose];

    _positioningView = nil;
    [_popoverWindow close];

    // popoverDidClose will be sent from popoverWindowDidClose, since
    // the popover window will close asynchronously when animating.
}


#pragma mark -
#pragma mark Action

- (IBAction)performClose:(id)sender
{
    if ([_popoverWindow isClosing])
        return;

    if (![self _popoverShouldClose])
        return;

    [self _close];
}


#pragma mark -
#pragma mark Delegates

- (BOOL)_popoverWindowShouldClose
{
    [self performClose:self];

    // We return NO, because we want the CPPopover to determine
    // if the popover window can be closed and to give us a chance
    // to send delegate messages.
    return NO;
}

- (void)_popoverWindowDidClose
{
    if (_implementedDelegateMethods & CPPopoverDelegate_popover_didClose_)
        [_delegate popoverDidClose:self];
}

- (void)_popoverWindowDidShow
{
    if (_implementedDelegateMethods & CPPopoverDelegate_popover_didShow_)
        [_delegate popoverDidShow:self];
}

- (BOOL)_popoverShouldClose
{
    if (_implementedDelegateMethods & CPPopoverDelegate_popover_shouldClose_)
        return [_delegate popoverShouldClose:self];

    return YES;
}

- (void)_popoverWillClose
{
    if (_implementedDelegateMethods & CPPopoverDelegate_popover_willClose_)
        [_delegate popoverWillClose:self];
}

- (void)_popoverWillShow
{
    if (_implementedDelegateMethods & CPPopoverDelegate_popover_willShow_)
        [_delegate popoverWillShow:self];
}

@end

@implementation CPPopover (Deprecated)

- (void)setBehaviour:(int)aBehavior
{
    _CPReportLenientDeprecation(self, _cmd, @selector(setBehavior:));

    [self setBehavior:aBehavior];
}

@end

var CPPopoverNeedsNewPopoverWindowKey = @"CPPopoverNeedsNewPopoverWindowKey",
    CPPopoverAppearanceKey = @"CPPopoverAppearanceKey",
    CPPopoverAnimatesKey = @"CPPopoverAnimatesKey",
    CPPopoverContentViewControllerKey = @"CPPopoverContentViewControllerKey",
    CPPopoverDelegateKey = @"CPPopoverDelegateKey",
    CPPopoverBehaviorKey = @"CPPopoverBehaviorKey";

@implementation CPPopover (CPCoding)

- (id)initWithCoder:(CPCoder)aCoder
{
    self = [super initWithCoder:aCoder];

    if (self)
    {
        _appearance = [aCoder decodeIntForKey:CPPopoverAppearanceKey];
        _animates = [aCoder decodeBoolForKey:CPPopoverAnimatesKey];
        _contentViewController = [aCoder decodeObjectForKey:CPPopoverContentViewControllerKey];
        [self setDelegate:[aCoder decodeObjectForKey:CPPopoverDelegateKey]];
        [self setBehavior:[aCoder decodeIntForKey:CPPopoverBehaviorKey]];
    }
    return self;
}

- (void)encodeWithCoder:(CPCoder)aCoder
{
    [super encodeWithCoder:aCoder];

    [aCoder encodeInt:_appearance forKey:CPPopoverAppearanceKey];
    [aCoder encodeBool:_animates forKey:CPPopoverAnimatesKey];
    [aCoder encodeObject:_contentViewController forKey:CPPopoverContentViewControllerKey];
    [aCoder encodeObject:_delegate forKey:CPPopoverDelegateKey];
    [aCoder encodeInt:_behavior forKey:CPPopoverBehaviorKey];
}

@end

@implementation CPPopover (CPSynthesizedAccessors)

- (CPViewController)contentViewController
{
    return _contentViewController;
}

- (void)setContentViewController:(CPViewController)aValue
{
    _contentViewController = aValue;
}

- (BOOL)animates
{
    return _animates;
}

- (int)appearance
{
    return _appearance;
}

- (void)setAppearance:(int)aValue
{
    _appearance = aValue;
}

- (int)behavior
{
    return _behavior;
}

@end