CPURLRequest.j

Go to the documentation of this file.

/*
 * CPURLRequest.j
 * Foundation
 *
 * Created by Francisco Tolmasky.
 * Copyright 2008, 280 North, Inc.
 *
 * This library is free software; you can redistribute it and/or
 * modify it under the terms of the GNU Lesser General Public
 * License as published by the Free Software Foundation; either
 * version 2.1 of the License, or (at your option) any later version.
 *
 * This library is distributed in the hope that it will be useful,
 * but WITHOUT ANY WARRANTY; without even the implied warranty of
 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
 * Lesser General Public License for more details.
 *
 * You should have received a copy of the GNU Lesser General Public
 * License along with this library; if not, write to the Free Software
 * Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA
 */


@typedef CPURLRequestCachePolicy
CPURLRequestUseProtocolCachePolicy = 0;
CPURLRequestReloadIgnoringLocalCacheData = 1;
CPURLRequestReturnCacheDataElseLoad = 2;
CPURLRequestReturnCacheDataDontLoad = 3;

@implementation CPURLRequest : CPObject
{
    CPURL                       _URL;

    // FIXME: this should be CPData
    CPString                    _HTTPBody;
    CPString                    _HTTPMethod;
    BOOL                        _withCredentials;

    CPDictionary                _HTTPHeaderFields;
    CPTimeInterval              _timeoutInterval;
    CPURLRequestCachePolicy     _cachePolicy;
}

+ (id)requestWithURL:(CPURL)aURL
{
    return [[CPURLRequest alloc] initWithURL:aURL];
}

+ (id)requestWithURL:(CPURL)anURL cachePolicy:(CPURLRequestCachePolicy)aCachePolicy timeoutInterval:(CPTimeInterval)aTimeoutInterval
{
    return [[CPURLRequest alloc] initWithURL:anURL cachePolicy:aCachePolicy timeoutInterval:aTimeoutInterval];
}

- (id)init
{
    return [self initWithURL:nil];
}

- (id)initWithURL:(CPURL)anURL cachePolicy:(CPURLRequestCachePolicy)aCachePolicy timeoutInterval:(CPTimeInterval)aTimeoutInterval
{
    if (self = [self initWithURL:anURL])
    {
        _cachePolicy = aCachePolicy;
        _timeoutInterval = aTimeoutInterval;
        
        [self _updateCacheControlHeader];
    }

    return self;
}

- (id)initWithURL:(CPURL)aURL
{
    if (self = [super init])
    {
        [self setURL:aURL];

        _HTTPBody = @"";
        _HTTPMethod = @"GET";
        _HTTPHeaderFields = @{};
        _withCredentials = NO;
        _timeoutInterval = 60.0;
        _cachePolicy = CPURLRequestUseProtocolCachePolicy;

        [self setValue:"Thu, 01 Jan 1970 00:00:00 GMT" forHTTPHeaderField:"If-Modified-Since"];
        [self setValue:"XMLHttpRequest" forHTTPHeaderField:"X-Requested-With"];
        [self _updateCacheControlHeader];
    }

    return self;
}

- (void)setURL:(CPURL)aURL
{
    // Lenient and accept strings.
    _URL = new CFURL(aURL);
}

- (CPString)valueForHTTPHeaderField:(CPString)aField
{
    return [_HTTPHeaderFields objectForKey:aField];
}

- (void)setValue:(CPString)aValue forHTTPHeaderField:(CPString)aField
{
    [_HTTPHeaderFields setObject:aValue forKey:aField];
}

/*
  @ignore
*/
- (void)_updateCacheControlHeader
{
    switch (_cachePolicy)
    {
      case CPURLRequestUseProtocolCachePolicy:
          // TODO: implement everything about cache...
          [self setValue:"no-cache" forHTTPHeaderField:"Cache-Control"];
          break;

      case CPURLRequestReturnCacheDataElseLoad:
          [self setValue:"max-stale=31536000" forHTTPHeaderField:"Cache-Control"];
          break;

      case CPURLRequestReturnCacheDataDontLoad:
          [self setValue:"only-if-cached" forHTTPHeaderField:"Cache-Control"];
          break;

      case CPURLRequestReloadIgnoringLocalCacheData:
          [self setValue:"no-cache" forHTTPHeaderField:"Cache-Control"];
          break;

      default:
          [self setValue:"no-cache" forHTTPHeaderField:"Cache-Control"];
    }
}

@end

/*
    Implements the CPCopying Protocol for a CPURLRequest to provide deep copying for CPURLRequests
*/
@implementation CPURLRequest (CPCopying)
{
}

- (id)copy
{
    var request = [[CPURLRequest alloc] initWithURL:[self URL]];
    [request setHTTPBody:[self HTTPBody]];
    [request setHTTPMethod:[self HTTPMethod]];
    [request setWithCredentials:[self withCredentials]];
    request._HTTPHeaderFields = [self allHTTPHeaderFields];

    return request;
}

@end

@implementation CPURLRequest (CPSynthesizedAccessors)

- (CPURL)URL
{
    return _URL;
}

- (void)setURL:(CPURL)aValue
{
    _URL = aValue;
}

- (CPString)HTTPBody
{
    return _HTTPBody;
}

- (void)setHTTPBody:(CPString)aValue
{
    _HTTPBody = aValue;
}

- (CPString)HTTPMethod
{
    return _HTTPMethod;
}

- (void)setHTTPMethod:(CPString)aValue
{
    _HTTPMethod = aValue;
}

- (BOOL)withCredentials
{
    return _withCredentials;
}

- (void)setWithCredentials:(BOOL)aValue
{
    _withCredentials = aValue;
}

- (CPDictionary)allHTTPHeaderFields
{
    return _HTTPHeaderFields;
}

- (CPTimeInterval)timeoutInterval
{
    return _timeoutInterval;
}

- (CPURLRequestCachePolicy)cachePolicy
{
    return _cachePolicy;
}

@end