CPPasteboard.j

Go to the documentation of this file.

/*
 * CPPasteboard.j
 * AppKit
 *
 * Created by Francisco Tolmasky.
 * Copyright 2008, 280 North, Inc.
 *
 * This library is free software; you can redistribute it and/or
 * modify it under the terms of the GNU Lesser General Public
 * License as published by the Free Software Foundation; either
 * version 2.1 of the License, or (at your option) any later version.
 *
 * This library is distributed in the hope that it will be useful,
 * but WITHOUT ANY WARRANTY; without even the implied warranty of
 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
 * Lesser General Public License for more details.
 *
 * You should have received a copy of the GNU Lesser General Public
 * License along with this library; if not, write to the Free Software
 * Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA
 */



@typedef DataTransfer

CPGeneralPboard         = @"CPGeneralPboard";
CPFontPboard            = @"CPFontPboard";
CPRulerPboard           = @"CPRulerPboard";
CPFindPboard            = @"CPFindPboard";
CPDragPboard            = @"CPDragPboard";

CPColorPboardType       = @"CPColorPboardType";
CPFilenamesPboardType   = @"CPFilenamesPboardType";
CPFontPboardType        = @"CPFontPboardType";
CPHTMLPboardType        = @"CPHTMLPboardType";
CPStringPboardType      = @"CPStringPboardType";
CPURLPboardType         = @"CPURLPboardType";
CPImagesPboardType      = @"CPImagesPboardType";
CPVideosPboardType      = @"CPVideosPboardType";
CPRTFPboardType         = @"CPRTFPboardType";
_CPSmartPboardType      = @"_CPSmartPboardType";

UTF8PboardType          = @"public.utf8-plain-text";

// Deprecated
CPImagePboardType       = @"CPImagePboardType";


var CPPasteboards = nil;

@implementation CPPasteboard : CPObject
{
    CPArray         _types;
    CPDictionary    _owners;
    CPDictionary    _provided;

    unsigned        _changeCount;
    CPString        _stateUID;
}

/*
    @ignore
*/
+ (void)initialize
{
    if (self !== [CPPasteboard class])
        return;

    [self setVersion:1.0];

    CPPasteboards = @{};
}

+ (id)generalPasteboard
{
    return [CPPasteboard pasteboardWithName:CPGeneralPboard];
}

+ (id)pasteboardWithName:(CPString)aName
{
    var pasteboard = [CPPasteboards objectForKey:aName];

    if (pasteboard)
        return pasteboard;

    pasteboard = [[CPPasteboard alloc] _initWithName:aName];
    [CPPasteboards setObject:pasteboard forKey:aName];

    return pasteboard;
}

/* @ignore */
- (id)_initWithName:(CPString)aName
{
    self = [super init];

    if (self)
    {
//        _name = aName;
        _types = [];

        _owners = @{};
        _provided = @{};

        _changeCount = 0;
    }

    return self;
}

- (unsigned)addTypes:(CPArray)types owner:(id)anOwner
{
    var i = 0,
        count = types.length;

    for (; i < count; ++i)
    {
        var type = types[i];

        if (![_owners objectForKey:type])
        {
            [_types addObject:type];
            [_provided removeObjectForKey:type];
        }

        [_owners setObject:anOwner forKey:type];
    }

    return ++_changeCount;
}

- (unsigned)declareTypes:(CPArray)types owner:(id)anOwner
{
    [_types setArray:types];

    _owners = @{};
    _provided = @{};

    if (anOwner)
    {
        var count = _types.length;
        while (count--)
            [_owners setObject:anOwner forKey:_types[count]];
    }

    return ++_changeCount;
}

- (BOOL)setData:(CPData)aData forType:(CPString)aType
{
    [_provided setObject:aData forKey:aType];

    if (aType === CPStringPboardType)
        [self setData:aData forType:UTF8PboardType];

    return YES;
}

- (BOOL)setPropertyList:(id)aPropertyList forType:(CPString)aType
{
    return [self setData:[CPPropertyListSerialization dataFromPropertyList:aPropertyList format:CPPropertyList280NorthFormat_v1_0] forType:aType];
}

- (void)setString:(CPString)aString forType:(CPString)aType
{
    // Putting a non-string on the string pasteboard can lead to strange crashes.
    if (aString && aString.isa && ![aString isKindOfClass:CPString])
        [CPException raise:CPInvalidArgumentException reason:"CPPasteboard setString:forType: must be called with a string."];

    [self setPropertyList:aString forType:aType];
}

// Determining Types
- (CPString)availableTypeFromArray:(CPArray)anArray
{
    return [anArray firstObjectCommonWithArray:[self types]];
}

- (CPArray)types
{
    return _types;
}

// Reading data
- (unsigned)changeCount
{
    return _changeCount;
}

- (CPData)dataForType:(CPString)aType
{
    var data = [_provided objectForKey:aType];

    if (data)
        return data;

    var owner = [_owners objectForKey:aType];

    if (owner)
    {
        [owner pasteboard:self provideDataForType:aType];
        return [_provided objectForKey:aType];
    }

    if (aType === CPStringPboardType)
        return [self dataForType:UTF8PboardType];

    return nil;
}

- (id)propertyListForType:(CPString)aType
{
    var data = [self dataForType:aType];

    if (data)
        return [CPPropertyListSerialization propertyListFromData:data format:CPPropertyList280NorthFormat_v1_0];

    return nil;
}

- (CPString)stringForType:(CPString)aType
{
    return [self propertyListForType:aType];
}

/* @ignore */
- (CPString)_generateStateUID
{
    var bits = 32;

    _stateUID = @"";

    while (bits--)
        _stateUID += FLOOR(RAND() * 16.0).toString(16).toUpperCase();

    return _stateUID;
}

/* @ignore */
- (CPString)_stateUID
{
    return _stateUID;
}

@end

#if PLATFORM(DOM)

var DOMDataTransferPasteboard = nil;

@implementation _CPDOMDataTransferPasteboard : CPPasteboard
{
    DataTransfer    _dataTransfer;
}

+ (_CPDOMDataTransferPasteboard)DOMDataTransferPasteboard
{
    if (!DOMDataTransferPasteboard)
        DOMDataTransferPasteboard = [[_CPDOMDataTransferPasteboard alloc] init];

    return DOMDataTransferPasteboard;
}

- (void)_setDataTransfer:(DataTransfer)aDataTransfer
{
    _dataTransfer = aDataTransfer;
}

- (void)_setPasteboard:(CPPasteboard)aPasteboard
{
    _dataTransfer.clearData();

    var types = [aPasteboard types],
        count = types.length;

    while (count--)
    {
        var type = types[count];

        if (type === CPStringPboardType)
            _dataTransfer.setData(type, [aPasteboard stringForType:type]);
        else
            _dataTransfer.setData(type, [[aPasteboard dataForType:type] rawString]);
    }
}

- (CPArray)types
{
    return Array.prototype.slice.apply(_dataTransfer.types);
}

- (CPData)dataForType:(CPString)aType
{
    var dataString = _dataTransfer.getData(aType);

    if (aType === CPStringPboardType)
        return [CPData dataFromPropertyList:dataString format:kCFPropertyList280NorthFormat_v1_0];

    return [CPData dataWithRawString:dataString];
}

- (id)propertyListForType:(CPString)aType
{
    if (aType === CPStringPboardType)
        return _dataTransfer.getData(aType);

    return [CPPropertyListSerialization propertyListFromData:[self dataForType:aType] format:CPPropertyListUnknownFormat];
}

@end

#endif